Für einen Dienstplan, eine Anwesenheitsliste oder ein Projekttagebuch brauchen Sie eine Datumsliste ohne Samstage und Sonntage. Excel erstellt solche Listen ohne Handarbeit, auf Wunsch auch ohne Feiertage.
Die Kurzlösung
Steht das erste Datum in A2, schreiben Sie in A3 diese Formel und ziehen sie nach unten:
=ARBEITSTAG(A2;1)
ARBEITSTAG liefert den nächsten Werktag nach dem angegebenen Datum. Auf einen Freitag folgt also der Montag. Ohne Formel geht es mit dem Ausfüllkästchen, siehe unten.
Ohne Formel: Wochentage ausfüllen
- Geben Sie das erste Datum ein, zum Beispiel 05.06.2026.
- Ziehen Sie das Ausfüllkästchen (das kleine Quadrat unten rechts an der Zelle) mit gedrückter rechter Maustaste nach unten.
- Wählen Sie beim Loslassen im Kontextmenü „Wochentage ausfüllen“.
Alternativ ziehen Sie mit der linken Maustaste und wählen danach über das Symbol „Auto-Ausfülloptionen“ den Eintrag „Wochentage ausfüllen“. Excel trägt dann Fr 05.06., Mo 08.06., Di 09.06., Mi 10.06. und Do 11.06. ein. Die Werte sind feste Datumswerte, sie ändern sich nicht, wenn Sie das Startdatum später anpassen.
Mit Feiertagen
Feiertage berücksichtigt ARBEITSTAG über ein drittes Argument. Schreiben Sie die Feiertage in einen Bereich, etwa H2:H20, und geben Sie ihm einen Namen, zum Beispiel Feiertage:
=ARBEITSTAG(A2;1;Feiertage)
| Start | ohne Feiertage | mit Feiertag 04.06.2026 |
|---|---|---|
| Mo 01.06.2026 | Mo 01.06. | Mo 01.06. |
| Di 02.06. | Di 02.06. | |
| Mi 03.06. | Mi 03.06. | |
| Do 04.06. | Fr 05.06. | |
| Fr 05.06. | Mo 08.06. | |
| Mo 08.06. | Di 09.06. |
Welche Tage Feiertage sind, hängt vom Bundesland ab. Excel kennt sie nicht von selbst, die Liste pflegen Sie einmal im Jahr. Einfacher geht es mit unserem Excel Feiertagsrechner: Er berechnet alle Feiertage jedes Bundeslands, Österreichs und der Schweiz für die Jahre 2000 bis 2050, einschließlich Ostern, Pfingsten und regionaler Sonderfälle wie Fronleichnam oder Mariä Himmelfahrt. Die Liste übernehmen Sie als Bereich Feiertage in Ihre Datei.
Ganze Liste mit einer Formel (Excel für Microsoft 365)
In Excel für Microsoft 365 erzeugt eine einzige Formel die ganze Liste. Diese Formel liefert 20 Werktage ab dem Datum in A2, das Startdatum eingeschlossen:
=ARBEITSTAG(A2-1;SEQUENZ(20);Feiertage)
SEQUENZ(20) erzeugt die Zahlen 1 bis 20, ARBEITSTAG rechnet von jedem Wert aus. Das -1 sorgt dafür, dass das Startdatum selbst in der Liste steht, wenn es ein Werktag ist. Formatieren Sie die Zellen als Datum, sonst sehen Sie Zahlen. Mit dem benutzerdefinierten Zahlenformat TTT TT.MM.JJJJ erscheint der Wochentag gleich mit, etwa „Mo 01.06.2026“.
Mit Wochentag und Kalenderwoche
Für einen Dienstplan oder ein Projekttagebuch sind Wochentag und Kalenderwoche als eigene Spalten praktischer. Diese Formel liefert zehn Werktage mit beidem:
=LET(d;ARBEITSTAG(A2-1;SEQUENZ(10);Feiertage);
HSTAPELN(d;TEXT(d;"TTTT");ISOKALENDERWOCHE(d)))
| Datum | Wochentag | KW |
|---|---|---|
| 01.06.2026 | Montag | 23 |
| 02.06.2026 | Dienstag | 23 |
| 03.06.2026 | Mittwoch | 23 |
| 05.06.2026 | Freitag | 23 |
| 08.06.2026 | Montag | 24 |
Der 04.06.2026 fehlt, weil er im Beispiel als Feiertag eingetragen ist. ISOKALENDERWOCHE zählt die Wochen nach der in Deutschland üblichen Norm ISO 8601, bei der die erste Woche die mit dem ersten Donnerstag des Jahres ist. Die ältere Funktion KALENDERWOCHE zählt ohne zweites Argument anders und liefert um den Jahreswechsel abweichende Wochen.
Alle Werktage eines Monats
Statt einer festen Anzahl brauchen Sie oft genau die Werktage eines Monats, etwa für eine Anwesenheitsliste. Diese Formel erzeugt alle Tage des Juni 2026 und behält nur Montag bis Freitag ohne Feiertage:
=LET(a;DATUM(2026;6;1);
d;SEQUENZ(TAG(MONATSENDE(a;0));;a);
FILTER(d;(WOCHENTAG(d;2)<6)*ISTNV(XVERGLEICH(d;Feiertage))))
Das Ergebnis sind 21 Tage: 22 Werktage im Juni 2026 abzüglich des Feiertags am 04.06. SEQUENZ(30;;a) zählt vom Monatsersten 30 Tage hoch, WOCHENTAG(d;2)<6 lässt Samstag und Sonntag weg, XVERGLEICH sucht jeden Tag in der Feiertagsliste. Für einen anderen Monat ändern Sie nur das Datum in der ersten Zeile oder verweisen auf eine Zelle.
Andere Arbeitswochen
Wer auch samstags arbeitet, nimmt ARBEITSTAG.INTL. Das dritte Argument legt mit sieben Ziffern von Montag bis Sonntag fest, welche Tage frei sind (1 = frei):
| Arbeitswoche | Formel |
|---|---|
| Montag bis Freitag | =ARBEITSTAG.INTL(A2;1;"0000011") |
| Montag bis Samstag | =ARBEITSTAG.INTL(A2;1;"0000001") |
| Montag bis Samstag (Kurzform) | =ARBEITSTAG.INTL(A2;1;11) |
Die klassische Formel
In älteren Anleitungen steht oft eine Formel mit WOCHENTAG:
=A2+WENN(WOCHENTAG(A2;2)=5;3;WENN(WOCHENTAG(A2;2)=6;2;1))
Sie addiert am Freitag 3 Tage, am Samstag 2 und sonst 1. Das Ergebnis stimmt, ARBEITSTAG ist aber kürzer und kann zusätzlich Feiertage.
Typische Fehler
- Startdatum am Wochenende: Die erste Zelle übernimmt Excel so, wie Sie sie eingeben. Beginnt die Liste an einem Samstag, steht dieser Samstag oben. Mit
=ARBEITSTAG(Datum-1;1)machen Sie aus jedem Startdatum den nächsten Werktag. - Zahlen statt Datum: Zeigt die Liste Werte wie 46178, ist die Zelle als Zahl formatiert. Stellen Sie das Format Datum ein.
- Feiertage als Text: Ein Feiertag, der als Text im deutschen Format in der Liste steht, wird von ARBEITSTAG meist noch erkannt. Verlassen Sie sich nicht darauf: Andere Formate werden falsch gelesen. Tragen Sie Feiertage als echte Datumswerte ein und prüfen Sie die Liste mit
=ISTZAHL(H2). - Anzahl Werktage gesucht: Wie viele Werktage ein Zeitraum hat, berechnet NETTOARBEITSTAGE, zum Beispiel
=NETTOARBEITSTAGE(DATUM(2026;6;1);DATUM(2026;6;30))mit dem Ergebnis 22. - Falsche Kalenderwoche am Jahresanfang: KALENDERWOCHE ohne zweites Argument zählt nach US-Zählweise. Für deutsche Pläne nehmen Sie ISOKALENDERWOCHE oder
KALENDERWOCHE(Datum;21).
Mit KI schneller zum Ziel
Eine Formel für Werktage schreiben ChatGPT, Claude oder Copilot zuverlässig. Heikel wird es bei den Feiertagen. Bitten Sie eine KI um die Feiertage eines Jahres, erhalten Sie eine plausible Liste, in der aber bewegliche Feiertage falsch berechnet sein oder regionale Feiertage fehlen können. Fronleichnam gilt nicht in jedem Bundesland, und der Buß- und Bettag nur in Sachsen. Prüfen Sie eine solche Liste deshalb gegen eine verlässliche Quelle, bevor Dienstpläne oder Fristen darauf beruhen, oder nehmen Sie gleich den Feiertagsrechner, der die Feiertage nach festen Regeln berechnet.
Mehr zu Möglichkeiten und Grenzen der Werkzeuge im Beitrag ChatGPT und Copilot in Excel: Möglichkeiten und Grenzen. Wie wir KI in Projekten einsetzen, um Aufwand und Kosten zu senken, steht unter KI und Automatisierung.
Aus der Praxis: vom Kalender zur Personalplanung
Eine Datumsliste ist der Anfang vieler Planungen: Dienstpläne mit Schichten, Urlaubsplanung mit Resttagen, Kapazitätsplanung für Projekte. In solchen Dateien greifen Werktage, Feiertage je Standort, Teilzeitmodelle und Abwesenheiten ineinander, und eine falsche Regel verfälscht alle Auswertungen. Wir bauen solche Planungen so, dass Feiertage automatisch für jedes Bundesland stimmen und die Datei mit wenigen Klicks für das nächste Jahr bereit ist. Mehr dazu unter Excel-Programmierung.
Passende Beiträge
Lernen oder machen lassen?
Excel-Formeln, die im Alltag sitzen.
In einer Schulung arbeiten wir mit Ihren eigenen Dateien, damit Sie das Gelernte am nächsten Tag nutzen. Oder wir bauen die Lösung direkt für Sie.
