Datumsdifferenz in Excel: Tage, Monate und Jahre berechnen

Wie viele Tage liegen zwischen Bestellung und Lieferung, wie lange läuft ein Vertrag schon, wie alt ist ein Mitarbeiter? Für solche Fragen berechnet Excel die Differenz zwischen zwei Datumswerten. Je nach Frage brauchen Sie Tage, volle Monate, volle Jahre oder eine Angabe wie „2 Jahre, 3 Monate und 14 Tage“.

Die Kurzlösung

Steht das Startdatum in A2 und das Enddatum in B2, liefern diese Formeln die wichtigsten Werte:

GesuchtFormel
Tage=B2-A2
volle Monate=DATEDIF(A2;B2;"m")
volle Jahre=DATEDIF(A2;B2;"y")
Arbeitstage (Montag bis Freitag)=NETTOARBEITSTAGE(A2;B2)
Jahre mit Nachkommastellen=BRTEILJAHRE(A2;B2;1)

Für die Tage genügt eine einfache Subtraktion, weil Excel ein Datum intern als fortlaufende Zahl speichert. Formatieren Sie die Ergebniszelle als Zahl, sonst zeigt Excel das Ergebnis als Datum an.

Die Funktion DATEDIF

DATEDIF berechnet die Differenz in der Einheit, die Sie im dritten Argument angeben:

=DATEDIF(Ausgangsdatum;Enddatum;Einheit)

Die Funktion erscheint nicht im Funktionsassistenten und bietet beim Eintippen keine Hilfe an. Sie funktioniert trotzdem in allen Excel-Versionen. Das Beispiel rechnet vom 15.01.2012 bis zum 29.04.2014:

EinheitBedeutungFormelErgebnis
"d"Tage=DATEDIF(A2;B2;"d")835
"m"volle Monate=DATEDIF(A2;B2;"m")27
"y"volle Jahre=DATEDIF(A2;B2;"y")2
"yd"Tage ohne die vollen Jahre=DATEDIF(A2;B2;"yd")105
"ym"Monate ohne die vollen Jahre=DATEDIF(A2;B2;"ym")3
"md"Tage ohne Monate und Jahre=DATEDIF(A2;B2;"md")14

Jahre, Monate und Tage in einem Satz

Für eine lesbare Angabe wie „2 Jahre, 3 Monate, 14 Tage“ setzen Sie die Teile zusammen. Mit LET (Excel für Microsoft 365 und Excel 2021) bleibt die Formel übersichtlich:

=LET(s;A2;e;B2;
     j;DATEDIF(s;e;"y");
     m;DATEDIF(s;e;"ym");
     t;e-EDATUM(s;12*j+m);
     j&" Jahre, "&m&" Monate, "&t&" Tage")

In älteren Versionen ohne LET:

=DATEDIF(A2;B2;"y")&" Jahre, "&DATEDIF(A2;B2;"ym")&" Monate, "&B2-EDATUM(A2;DATEDIF(A2;B2;"m"))&" Tage"

Beide Formeln berechnen die Resttage nicht mit "md", sondern über EDATUM. Der Grund steht unter „Typische Fehler“.

Eine ganze Liste mit einer Formel (Microsoft 365)

Für eine Vertrags- oder Mitarbeiterliste müssen Sie die Formel in Excel für Microsoft 365 nicht mehr nach unten kopieren. MAP rechnet jede Zeile einzeln und gibt alle Ergebnisse auf einmal aus. Stehen die Startdaten in A2:A4 und die Enddaten in B2:B4:

=MAP(A2:A4;B2:B4;LAMBDA(s;e;LET(
     j;DATEDIF(s;e;"y");
     m;DATEDIF(s;e;"ym");
     t;e-EDATUM(s;12*j+m);
     j&" Jahre, "&m&" Monate, "&t&" Tage")))
StartEndeErgebnis
15.01.201229.04.20142 Jahre, 3 Monate, 14 Tage
31.01.202401.03.20240 Jahre, 1 Monate, 1 Tage
30.06.202015.11.20266 Jahre, 4 Monate, 16 Tage

MAP übergibt der LAMBDA-Funktion Zeile für Zeile ein Startdatum s und ein Enddatum e. Mit A2:.A1000 und B2:.B1000 statt fester Bereiche wächst das Ergebnis mit, wenn Sie neue Zeilen anfügen. Der Punkt kürzt den Bereich auf die gefüllten Zellen.

Genauso zählt MAP die Arbeitstage für jede Zeile:

=MAP(A2:A4;B2:B4;LAMBDA(s;e;NETTOARBEITSTAGE(s;e;Feiertage)))

Warum der Umweg über MAP nötig ist, steht ebenfalls unter „Typische Fehler“.

Typische Fehler

  • Falsche Resttage mit „md“: Microsoft weist selbst darauf hin, dass die Einheit "md" in manchen Fällen falsch rechnet. Vom 31.01.2024 bis zum 01.03.2024 liefert =DATEDIF(A2;B2;"md") den Wert -1. Richtig sind ein Monat und ein Tag. Die Formel =B2-EDATUM(A2;DATEDIF(A2;B2;"m")) liefert hier korrekt 1. Verwenden Sie sie überall dort, wo Sie Resttage brauchen. Beachten Sie die Zählweise am Monatsende: Vom 31.01.2024 bis zum 29.02.2024 ergeben DATEDIF und diese Formel 0 Monate und 29 Tage, weil der Februar keinen 31. hat. Wer vom Monatsletzten zum Monatsletzten einen vollen Monat zählen möchte, muss das gesondert regeln.
  • Ganze Bereiche in EDATUM oder NETTOARBEITSTAGE: Die Formel =LET(s;A2:A4;e;B2:B4; …) sieht aus, als würde sie die Liste in einem Rutsch berechnen. EDATUM und NETTOARBEITSTAGE verarbeiten ganze Bereiche aber nicht zuverlässig. Im Beispiel oben erscheint in der ersten Zeile #WERT!, und in der zweiten Zeile stehen statt einem Tag 4398 Tage, ohne jede Fehlermeldung. Übergeben Sie die Werte deshalb wie oben gezeigt mit MAP einzeln.
  • Enddatum vor dem Startdatum: DATEDIF gibt dann den Fehler #ZAHL! zurück. Ist die Reihenfolge nicht sicher, sortieren Sie die Werte in der Formel: =DATEDIF(MIN(A2;B2);MAX(A2;B2);"d").
  • Datum als Text: Nach einem Import steht ein Datum oft als Text in der Zelle, erkennbar an der linksbündigen Ausrichtung. Ein Text im deutschen Format wie „11.03.2015“ wird von DATEDIF und beim Subtrahieren meist noch umgewandelt. Ein Text wie „03/11/2015“ wird dagegen als 3. November gelesen, und Funktionen wie SUMMEWENNS übergehen Textdaten ganz. Wandeln Sie solche Spalten deshalb mit Daten, Text in Spalten oder DATWERT in echte Datumswerte um.
  • Ergebnis sieht aus wie ein Datum: Bei =B2-A2 übernimmt Excel manchmal das Datumsformat. Stellen Sie die Zelle auf das Format Zahl um.

Praxisbeispiele

Alter oder Betriebszugehörigkeit zum heutigen Tag:

=DATEDIF(A2;HEUTE();"y")

Arbeitstage ohne Feiertage, wenn die Feiertage in einem Bereich namens Feiertage stehen:

=NETTOARBEITSTAGE(A2;B2;Feiertage)

Andere Wochenenden, etwa nur Sonntag frei, berücksichtigt NETTOARBEITSTAGE.INTL mit dem dritten Argument 11.

Die Feiertage selbst müssen Sie nicht von Hand zusammensuchen. Unser Excel Feiertagsrechner listet alle Feiertage jedes Bundeslands, Österreichs und der Schweiz für die Jahre 2000 bis 2050, einschließlich Ostern und der beweglichen Feiertage. Die Liste übernehmen Sie als Bereich Feiertage in Ihre Berechnung.

Mit KI schneller zum Ziel

Fragen Sie ChatGPT oder Copilot nach der Dauer in Jahren, Monaten und Tagen, kommt als Antwort gern DATEDIF mit der Einheit "md", also genau die Variante, vor der Microsoft selbst warnt. Die Formel sieht richtig aus und liefert in den meisten Fällen auch das passende Ergebnis. Erst am Monatsende rechnet sie falsch. Prüfen Sie KI-Vorschläge für Datumsberechnungen deshalb mit einem Grenzfall wie 31.01.2024 bis 01.03.2024. Mehr zu Stärken und Schwächen der Werkzeuge im Beitrag ChatGPT und Copilot in Excel: Möglichkeiten und Grenzen, zu unserem eigenen Einsatz von KI auf der Seite KI und Automatisierung.

Aus der Praxis

Datumsberechnungen stecken in vielen Listen: Fristen in der Vertragsverwaltung, Betriebszugehörigkeit für Jubiläen, Lieferzeiten im Einkauf. Die Formeln dazu sind kurz, die Fallstricke liegen in den Sonderfällen wie Monatsenden, Feiertagen oder Daten als Text. In unseren Excel-Schulungen üben wir solche Formeln direkt an Ihren eigenen Dateien, damit Sie sie am nächsten Tag sicher einsetzen.

Passende Beiträge

Lernen oder machen lassen?

Excel-Formeln, die im Alltag sitzen.

In einer Schulung arbeiten wir mit Ihren eigenen Dateien, damit Sie das Gelernte am nächsten Tag nutzen. Oder wir bauen die Lösung direkt für Sie.