E-Rechnungen per VBA erzeugen: die SmartTools E-Rechnung VBA-Bibliothek für Excel

Wer viele Rechnungen aus Excel erzeugt oder den kompletten Ablauf auf einen Klick reduzieren möchte, kommt an VBA nicht vorbei. Die SmartTools E-Rechnung VBA-Bibliothek 2.5 für Excel stellt dafür ein Objektmodell bereit, mit dem Sie E-Rechnungen in allen ZUGFeRD Profilen und als XRechnung erzeugen, einlesen, prüfen und anzeigen.

Excel-Inside Solutions setzt die Bibliothek in Kundenprojekten ein. In diesem Artikel zeigen wir den Aufbau einer Lösung anhand praxisnaher Codebeispiele. Grundlagen zur Pflicht und zu den Formaten finden Sie im Hauptartikel E-Rechnungspflicht erklärt.

Einrichtung in wenigen Minuten

1. Installation. Die Bibliothek wird automatisch installiert und in Windows registriert.
2. Verweis setzen. Öffnen Sie in Ihrer Rechnungsmappe die VBA Entwicklungsumgebung mit Alt und F11. Unter Extras und Verweise aktivieren Sie die SmartTools Bibliothek.
3. Musterlösung ansehen. Bevor Sie eigenen Code schreiben, lohnt ein Blick in die mitgelieferte Musterlösung. Dort finden Sie die genauen Klassennamen für jedes Profil und vollständige Abläufe inklusive aller Pflichtfelder.

Beispiel 2: Rechnungspositionen in einer Schleife übertragen

Die Positionen stehen in der Vorlage untereinander. Eine Schleife liest jede Zeile aus, legt ein Positionsobjekt an und hängt es an die Rechnung an. Das Beispiel verwendet die Positionsklasse für das Profil Extended, das auch mehrstufige Unterpositionen erlaubt. Für andere Profile verwenden Sie die entsprechende Klasse aus der Musterlösung.

Copy
'***************************************************
' VBA-Code erstellt 9/2026
' A. Eckl - Excel-Inside Solutions
' https://excel-inside.de
' Rechnungspositionen ab Zeile 20 in die E-Rechnung
' uebertragen (Spalten A bis E)
'***************************************************
Sub PositionenUebertragen(objInvoice As Object, wsRechnung As Worksheet)
  Dim objLine As SmartTools_Invoicing_EN16931_ZUGFeRD_Extended_InvoiceLine
  Dim lngZeile As Long

  lngZeile = 20

  '** Bis zur ersten leeren Zeile in Spalte A lesen
  Do While Len(wsRechnung.Cells(lngZeile, 1).Value) > 0
    Set objLine = New SmartTools_Invoicing_EN16931_ZUGFeRD_Extended_InvoiceLine
    With objLine
      .Id = CStr(wsRechnung.Cells(lngZeile, 1).Value)
      .ItemInformation.Name = wsRechnung.Cells(lngZeile, 2).Value
      .InvoicedQuantity = wsRechnung.Cells(lngZeile, 3).Value
      '** Einheitencode, z.B. H87 fuer Stueck oder HUR fuer Stunde
      .InvoicedQuantityUnitOfMeasureCode = wsRechnung.Cells(lngZeile, 4).Value
      '** Preise immer auf zwei Nachkommastellen runden
      .PriceDetails.NetPrice = Round(wsRechnung.Cells(lngZeile, 5).Value, 2)
    End With

    objInvoice.AddLine objLine
    lngZeile = lngZeile + 1
  Loop
End Sub

Beispiel 4: Vor dem Versand prüfen und anzeigen

Die Methode Validate prüft die E-Rechnung gegen die offiziellen Regeln und liefert ein Array mit den gefundenen Verstößen. Die folgende Hilfsfunktion ermittelt die Anzahl robust, auch wenn das Ergebnis leer ist. Ist alles in Ordnung, öffnet sich die Übersicht der Bibliothek zur Sichtkontrolle.

Copy
'***************************************************
' VBA-Code erstellt 9/2026
' A. Eckl - Excel-Inside Solutions
' https://excel-inside.de
' E-Rechnung validieren, Ergebnis melden und die
' fertige Rechnung zur Kontrolle anzeigen
'***************************************************
Function AnzahlVerstoesse(arrVerstoesse As Variant) As Long
  '** Leeres oder nicht belegtes Ergebnis ergibt 0
  On Error GoTo KeinErgebnis
  AnzahlVerstoesse = UBound(arrVerstoesse) - LBound(arrVerstoesse) + 1
  Exit Function
KeinErgebnis:
  AnzahlVerstoesse = 0
End Function

Sub RechnungPruefen(objInvoice As Object, strDatei As String)
  Dim arrInvoiceViolations As Variant
  Dim lngAnzahl As Long

  arrInvoiceViolations = objInvoice.Validate()
  lngAnzahl = AnzahlVerstoesse(arrInvoiceViolations)

  If lngAnzahl = 0 Then
    '** Gueltig: Rechnung zur Sichtkontrolle anzeigen
    xlE_Rechnung.ShowInvoiceOverview strDatei
  Else
    MsgBox "Die E-Rechnung enthaelt " & lngAnzahl & _
      " Regelverstoesse und sollte nicht versendet werden.", _
      vbExclamation, "Pruefung E-Rechnung"
  End If
End Sub

In der Musterlösung sehen Sie, wie die einzelnen Einträge des Arrays aufgebaut sind. So können Sie die Meldungen Ihren Anwendern im Klartext anzeigen oder als Protokoll neben der Rechnung speichern.

Tipps und Kniffe aus unseren Projekten

1. Benannte Bereiche statt Zelladressen. Wie in Beispiel 1 gezeigt, macht das Ihren Code unabhängig vom Layout der Vorlage.
2. Eine Prozedur je Aufgabe. Trennen Sie Kopfdaten, Positionen, Ausgabe und Prüfung in eigene Prozeduren. So wechseln Sie das Format, ohne den gesamten Code anzupassen.
3. Kaufmännisch runden. Rundungsdifferenzen zwischen Positionen und Summen gehören zu den häufigsten Gründen für Regelverstöße. Runden Sie Preise und Beträge konsequent auf zwei Nachkommastellen.
4. Einheitencodes aus einer Liste. E-Rechnungen verwenden genormte Codes wie H87 für Stück oder HUR für Stunde. Hinterlegen Sie diese in einer Auswahlliste, dann tippt niemand einen ungültigen Code ein.
5. Immer validieren. Bauen Sie die Prüfung fest in den Ablauf ein und verhindern Sie den Versand, solange Verstöße gemeldet werden.
6. Prüfprotokoll archivieren. Die Finanzverwaltung empfiehlt, das Ergebnis der Validierung zusammen mit der Rechnung aufzubewahren. Speichern Sie das Protokoll mit demselben Dateinamen neben der E-Rechnung.
7. Eindeutige Dateinamen. Verwenden Sie die Rechnungsnummer im Dateinamen. So findet sich jede E-Rechnung samt Protokoll sofort wieder.
8. Teilrechnungen und Schlussrechnungen. Die Bibliothek unterstützt auch diese Abrechnungsform, einschließlich der Verrechnung vorheriger Teilrechnungen in der Schlussrechnung. Testen Sie diesen Ablauf mit echten Projektdaten, bevor Sie live gehen.
9. Lizenzen planen. Benötigt wird eine Lizenz je Arbeitsplatz, an dem E-Rechnungen erzeugt werden. Für Entwickler, die Lösungen an viele Anwender verteilen, bietet SmartTools besondere Konditionen an.

Häufige Fragen zur E-Rechnung VBA-Bibliothek

Anfrage zur Integration

Beschreiben Sie kurz Ihre Rechnungsmappe und den gewünschten Ablauf. Gerne können Sie im Anschluss eine anonymisierte Beispielrechnung senden. Wir melden uns mit einer Einschätzung und einem unverbindlichen Angebot.

Wir freuen uns, dass Sie Interesse an unseren Dienstleistungen haben! Wenn Sie ein kostenloses und unverbindliches Angebot einholen möchten, füllen Sie bitte die nachstehenden Felder aus. Geben Sie uns einen detaillierten Überblick über Ihre Anfrage, damit wir Ihnen ein maßgeschneidertes Angebot unterbreiten können, das genau auf Ihre Bedürfnisse zugeschnitten ist.

Alternativ können Sie uns jederzeit eine E-Mail an Diese E-Mail-Adresse ist vor Spambots geschützt! Zur Anzeige muss JavaScript eingeschaltet sein. senden. Unser Team steht bereit, um Ihre Fragen zu beantworten und Ihnen bei Ihren Anliegen zu helfen.

Wir möchten betonen, dass wir Ihnen das Angebot völlig kostenfrei und ohne Verpflichtungen erstellen. In der Regel erhalten Sie innerhalb weniger Stunden eine Rückmeldung von uns. Ihre Zufriedenheit liegt uns am Herzen, und wir sind bestrebt, Ihnen schnell und effizient zu helfen.

Vielen Dank für Ihr Vertrauen in uns. Wir freuen uns auf Ihre Anfrage!

Name(*)

Invalid Input

Firma

Invalid Input

E-Mail Adresse:(*)

Keine gültige E-Mail Adresse

Rufnummer (optional)

Invalid Input

Nachricht(*)

Invalid Input

Dateianhänge (optional)

Invalid Input

Sicherheitsabfrage(*)

Ungültige Eingabe

Anfrage senden

Anfrage senden